[viesti Survo-keskustelupalstalla (2001-2013)]
| Kirjoittaja: | Seppo Mustonen |
|---|---|
| Sähköposti: | - |
| Päiväys: | 16.2.2003 21:25 |
Meikäläistä pyydettiin kertomaan tilastoihin liittyvistä asioista
YLE TV1:n viikottaiseen tiedeohjelmaan Prisma Studio.
Ohjelma nauhoitettiin vähän toista viikkoa sitten. Olin sopinut
esille tulevista asioista alustavasti ohjelman taustatoimittajan
Elina Heinon kanssa, mutta varsinaisessa studiokeskustelussa
haastattelijana oli Hyppe Salmi (molemmat erittäin sympaattisia
ihmisiä).
Tulevia vaaleja silmällä pitäen yhdeksi keskusteluteemaksi oli
otettu ns. vaaligallupit ts. puolueiden kannatusta mittaavat
haastattelututkimukset.
Tein omasta puolestani taustatyötä mm. sen verran, että otin yhteyttä
molempiin tällaisia kyselyjä tekeviin tahoihin (Taloustutkimus
ja Suomen Gallup) keskustelemalla kyselyistä vastaavien
henkilöiden kanssa. Yhteinen kanta näissä puhelinkeskusteluissa
oli se, että media pyrkii "ylitulkitsemaan" tuloksia tekemällä
isoja otsikoita pienistäkin näennäisistä muutoksista.
Jotta voisin antaa paremmin kuin vain inttämällä käsityksen
tulosten tyypillisestä tarkkuudesta, päätin ottaa koneen
mukaan studioon ja tehdä Survon avustuksella simulointikokeen,
joka menee kannettavallani läpi noin puolessa minuutissa.
En ole lainkaan varma, saivatko ohjelman tekijät soperteluistani
tarpeeksi selvää, enkä edes tiedä onko haastattelua näiltä osin
muokattu tai lyhennelty tai onko se peräti heitetty yli laidan.
Joka tapauksessa Survon käyttäjillä on tilaisuus tarkastella
asiaa omakohtaisesti, sillä olen liittänyt (katkoviivojen väliin)
otteen toimituskentästä, jossa on kaikki tarvittava tieto.
Avainasemassa on sukro KANNATUS, joka kentässä olevien tausta-
tietojen (puolueitten kuvitellut, todelliset kannatusosuudet,
otoskoko jne.) tekee tuon simulointikokeen sekä laskee että
piirtää tulokset.
Siirrä siis ainakin katkoviivojen välissä olevat rivit leikepöydän
kautta tyhjään Survon toimituskenttään, jos haluat kokeilla.
Tulet mm. näkemään, että puolueiden todellinen järjestys (alla olevilla
oletuksilla) tulee esille vain noin 66 prosentin todennäköisyydellä.
- Seppo
- - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
Esimerkki: Puolueiden kannatusosuuksien arviointi
Voit muuttaa tässä olevia olettamuksia ja koeparametreja.
Oletetaan, että puolueiden todelliset kannatusluvut prosentteina ovat:
Puolue A=24
Puolue B=23
Puolue C=20
Muut puolueet=33
Otoskoko=1500 (Haastateltavien lukumäärä)
Koetoistoja=10000 (Kuinka monta kertaa haastattelu uusitaan)
Siemenluku=2003 (Satunnaislukugeneraattoria varten)
/KANNATUS (Aktivoi tämä rivi, kun olet tallettanut sukron KANNATUS!)
DELETE / Siirrä ensin kohdistin kontrollisarakkeeseen ja aktivoi!
*TUTSAVE KANNATUS / Talleta sitten tämä sukro!
/
/ def Wotos=W1 WN=W2 Wrnd=W3 WA=W4 WB=W5 WC=W6 Wmuut=W7
/ def WABC=W8 WACB=W9 WBAC=W10 WBCA=W11 WCAB=W12 WCBA=W13
/ def Wpath=W14 Wt=W15 Wodotus=W16
/
*{init}{tempo -1}{R}
*{erase}{erase}SCRATCH{act}{line start}
*{save spec Otoskoko Wotos}
*{save spec Koetoistoja WN}
*{save spec Siemenluku Wrnd}
*{save spec A WA}
*{save spec B WB}
*{save spec C WC}
*{save spec puolueet Wmuut}
/
*{Wt=WA+WB}{Wt=Wt+WC}{Wt=Wt+Wmuut}
*{WA=WA/Wt}{WA=100*WA}
*{WB=WB/Wt}{WB=100*WB}
*{WC=WC/Wt}{WC=100*WC}
*{Wmuut=Wmuut/Wt}{Wmuut=100*Wmuut}{d20}{u20}
/
*MATRIX OSUUDET{R}
*/// Puolue Kannatus{R}
*A 1 {Wt=WA/100}{print Wt}{R}
*B 2 {Wt=WB/100}{print Wt}{R}
*C 3 {Wt=WC/100}{print Wt}{R}
*Muut 4 {Wt=Wmuut/100}{print Wt}{R}
*{R}
/
*GPLOT /DEL ALL{act}{R}
*GPLOT /LAYOUT SUR_G4.SYS{act}{R}
*MAT SAVE OSUUDET{act}{R}
*MAT A=OSUUDET{act}{R}
*MAT TRANSFORM A BY 100*X#{act}{R}
*MAT LOAD A{act}
/
*{R}
*{d3}{next word}{next word}{r}{save word WA}{d}{save word WB}{d}
*{save word WC}{d}{save word Wmuut}{R}
*.{copy}{R}
*{R}
*FRAMES=F1,F2,F3{R}
*F1=0,0,1600,1200,-1 FILL(-1)=0.2,0.2,0,0{R}
*F2=45,820,1200,350,-2 FILL(-2)=0.05,0.05,0,0{R}
*F3=45,100,1555,590,-3 FILL(-3)=0,0.0,1,0{R}
*{R}
*FRAME=0 MOUSE=MOUSE.MSG{R}
*{ref}GPLOT /FRAME / TOP=1{R}
*MODE=1600,1200 WHOME=0,40 WSIZE=(WX-10)/2,(WY-120)/2{R}
*TEXTS=T T=[Arial(65)],#LINES:CUR+3,CUR+17,50,1100,70{R}
*Puolueiden "todelliset" kannatusosuudet:{R}
*Puolue A {print WA} %{R}
*Puolue B {print WB} %{R}
*Puolue C {print WC} %{R}
*Muut puolueet {print Wmuut} %{R}
*{R}
*{R}
*Selvitetään, kuinka hyvin puolueiden A,B,C oikea järjestys{R}
*tulee esille kyselytutkimuksessa, jos saadaan vastaukset{R}
*1500 satunnaisesti valitulta henkilöltä.{R}
*{R}
*Tehdään simulointikoe: (siemenluku {print Wrnd}){R}
*Toistetaan tietokoneen avulla tällainen haastattelututkimus{R}
*{print WN} kertaa ja katsotaan, miten eri puolueitten{R}
*kannatusosuudet ja niiden väliset järjestykset vaihtelevat.{R}
*{ref set 1}{ref}{ref}{act}{ref jump 1}{R}
*{tempo +1}{10}{tempo -1}
*WIN MIN{act}{R}
*FILE DEL MOUSE.MSG{act}{R}
*{save datapath Wpath}{Wodotus=0}{R}
+ A: {line start}{erase}CHECK {print Wpath}MOUSE.MSG{act}{r}
*{save char Wt}{Wodotus=Wodotus+1}
/ Jatkuu näpäyttämällä ikkunaa tai kun 15 sekuntia on kulunut.
- if Wt '=' O then goto B
- if Wodotus > 15 then goto B
*{tempo +1}{wait 10}{tempo -1}{goto A}
+ B: {tempo -1}{R}
/
*WIN MAX{act}{R}
*GPLOT /SHOW MIN 1{act}{R}
*.{copy}{R}{R}{d24}{u23}
*{R}
* {form5}Arvotaan {write WN} kpl {write Wotos} havainnon otosta:{R}
*{R}
*Käytössä satunnaislukugeneraattori: RND=rand({print Wrnd}){R}
*FILE MAKE OTOKSET,{print Wotos},{print WN},X,1{act}{R}
*TRANSFORM OTOKSET BY #DISTR(OSUUDET){act}{R}
*.{copy}{R}
*{R}
*{R} {form5}
*Lasketaan eri puolueiden saamat kannatusluvut kussakin otoksessa:{R}
*{R}
*VARSTAT OTOKSET,A:2,#VAL,1 / Puolue A{act}{R}
*VARSTAT OTOKSET,B:2,#VAL,2 / Puolue B{act}{R}
*VARSTAT OTOKSET,C:2,#VAL,3 / Puolue C{act}{R}
*VARSTAT OTOKSET,Muut:2,#VAL,4 / Muut puolueet{act}{R}
*.{copy}{R}{d23}{u23}
*{R}
*{R}
* {form5} {R}
* {form5} Lasketaan tilastollisia {R}
* {form5} yhteenvetoja tuloksista: {R}
* {form5} {R}
*{tempo +1}{5}{tempo -1}{disp off}
*{R}
*FILE DEL KANNATUS{act}{R}
*FILE COPY OTOKSET TO KANNATUS / VARS=A,B,C,Muut{act}{R}
*.{copy}{R}
*{R}
*ERO_AB=A-B ERO_BC=B-C ERO_AC=A-C{R}
*VAR ERO_AB:2,ERO_BC:2,ERO_AC:2 TO KANNATUS{act}{R}
*.{copy}{R}
*{R}
*ABC:{R}
*SELECT=AB*BC*AC AB=ERO_AB,1,1000 BC=ERO_BC,1,1000 AC=ERO_AC,1,1000{R}
*MINSTAT KANNATUS,CUR+1 / VARS= {act}{R}
/
*{pre}c= {save word WABC}{l}=
/
*{R}
*{R}
*.{copy}{R}
*{R}
*ACB:{R}
*SELECT=AB*!BC*AC AB=ERO_AB,1,1000 BC=ERO_BC,1,1000 AC=ERO_AC,1,1000
*{R}
*MINSTAT KANNATUS,CUR+1 / VARS= {act}{R}
*{pre}c= {save word WACB}{l}={R}
*{R}
*.{copy}{R}
*{R}
*BAC:{R}
*SELECT=!AB*BC*AC AB=ERO_AB,1,1000 BC=ERO_BC,1,1000 AC=ERO_AC,1,1000
*{R}
*MINSTAT KANNATUS,CUR+1 / VARS= {act}{R}
*{pre}c= {save word WBAC}{l}={R}
*{R}
*.{copy}{R}
*{R}
*BCA:{R}
*SELECT=!AB*BC*!AC AB=ERO_AB,1,1000 BC=ERO_BC,1,1000 AC=ERO_AC,1,1000
*{R}
*MINSTAT KANNATUS,CUR+1 / VARS= {act}{R}
*{pre}c= {save word WBCA}{l}={R}
*{R}
*.{copy}{R}
*{R}
*CAB:{R}
*SELECT=AB*!BC*!AC AB=ERO_AB,1,1000 BC=ERO_BC,1,1000 AC=ERO_AC,1,1000
*{R}
*MINSTAT KANNATUS,CUR+1 / VARS= {act}{R}
*{pre}c= {save word WCAB}{l}={R}
*{R}
*.{copy}{R}
*{R}
*CBA:{R}
*SELECT=!AB*!BC*!AC AB=ERO_AB,1,1000 BC=ERO_BC,1,1000 AC=ERO_AC,1,1000
*{R}
*MINSTAT KANNATUS,CUR+1 / VARS= {act}{R}
*{pre}c= {save word WCBA}{l}={R}
*{R}
*.{copy}{R}
*{R}
*HEADER=[Arialb(70)],Eri_järjestysten_prosentuaaliset_osuudet{R}
*PEN=[Arialb(60)] LINETYPE=[Arialb(60)]{R}
*DATA ABC{R}
*Nimi Pros{R}
*A_B_C {WABC=WABC/WN}{WABC=100*WABC}{print WABC}{R}
*A_C_B {WACB=WACB/WN}{WACB=100*WACB}{print WACB}{R}
*B_A_C {WBAC=WBAC/WN}{WBAC=100*WBAC}{print WBAC}{R}
*B_C_A {WBCA=WBCA/WN}{WBCA=100*WBCA}{print WBCA}{R}
*C_A_B {WCAB=WCAB/WN}{WCAB=100*WCAB}{print WCAB}{R}
*C_B_A {WCBA=WCBA/WN}{WCBA=100*WCBA}{print WCBA}{R}
*{R}
*MODE=1600,1200 XDIV=200,1300,100 YDIV=150,900,150{R}
*LEGEND=- TICKLENGTH=10{R}
*SCALE=[Arialb(40)],0(20)80{R}
*FRAMES=F1,F2{R}
*F1=0,0,1600,1200,-1 FILL(-1)=0.1,0.1,0,0{R}
*F2=200,150,1300,900,-2 FILL(-2)=0.2,0.2,0,0{R}
*WHOME=WX/2,40 WSIZE=(WX-10)/2,(WY-120)/2{R}
*GPLOT ABC / TYPE=HBAR VALUES=##,9 SHADING=4 TOP=1{act}{R}
*.{copy}{R}
*{R}
*{d20}{u20}VAR APROS:4=100*A/{print Wotos} TO KANNATUS{act}{R}
*VAR BPROS:4=100*B/{print Wotos} TO KANNATUS{act}{R}
*HEADER=[Swissb(70)],Puolueen_A_kannatusarvion_vaihtelu_otoksissa{R}
*MODE=1600,1200 XDIV=200,1300,100 YDIV=150,900,150{R}
*PEN=[Arial(60)] LINETYPE=[Arial(60)][line_width(1)]{R}
*FILL(-3)=1,1,0,0 FILL=-3{R}
*XSCALE=18(1)30 YSCALE=0(200)800{R}
*TICKLENGTH=10 XLABEL={R}
*FRAMES=F1,F2{R}
*F1=0,0,1600,1200,-1 FILL(-1)=0.1,0.1,0,0{R}
*F2=200,150,1300,900,-2 FILL(-2)=0.2,0.2,0,0{R}
*WHOME=0,(WY-0)/2 WSIZE=(WX-10)/2,(WY-100)/2{R}
*APROS=19.5(0.2)30.5 FIT=[RED][line_width(10)],NORMAL{R}
*GHISTO KANNATUS,APROS / TOP=1 ROP=9{act}{R}
/ GPLOT /SHOW MIN 3{act}{R}
*.{copy}{R}
*{R}
*{d20}{u20}
*HEADER=[Swissb(70)],Puolueiden_A_ja_B_kannatusarvioiden
*_yhteisvaihtelu{R}
*CONTOUR=[line_color(-3)][line_width(2)],0.001,0.5,0.9,0.99{R}
*MODE=1600,1200 XDIV=200,1300,100 YDIV=200,850,150{R}
*PEN=[Arial(50)] LINETYPE=[Arial(50)][line_width(1)]{R}
*XSCALE=18(1)30 YSCALE=18(1)28 XJITTER=0.1 YJITTER=0.1
* POINT=[WHITE],3,1{R}
*FILL(-3)=0,0.5,1,0 TICKLENGTH=10{R}
*FRAMES=F1,F2{R}
*F1=0,0,1600,1200,-1 FILL(-1)=0.1,0.1,0,0{R}
*F2=200,200,1300,850,-2 FILL(-2)=1.0,1.0,0.5,0{R}
*XLABEL=A-puolue YLABEL=B-puolue{R}
*WHOME=WX/2,(WY-0)/2 WSIZE=(WX-10)/2,(WY-100)/2{R}
*GRID=XY{R}
*GPLOT KANNATUS,APROS,BPROS / TOP=1{act}{R}
*GPLOT /SHOW NORMAL 1{act}{R}
*{disp reset}
*{end}
- - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
| Vastaukset: |
|---|
Survo-keskustelupalstan (2001-2013) viestit arkistoitiin aika ajoin sukrolla, joka automaattisesti rakensi viesteistä (yli 1600 kpl) HTML-muotoisen sivukokonaisuuden. Vuoden 2013 alusta Survo-keskustelua on jatkettu entistäkin aktiivisemmin osoitteessa forum.survo.fi. Tervetuloa mukaan!